目次 †
デリゲート †
- デリゲートとはメソッドへの参照を示す特殊なクラスである。
- Delegateステートメントを利用して定義する。
- "delegete"には動詞の場合「委譲する」「委任する」、名詞の場合「代表」「代理人」という意味がある。
デリゲートの構文 †
Delegate Sub <デリゲート名>(<パラメータ1>, <パラメータ2>, …)
Delegate Function <デリゲート名>(<パラメータ1>, <パラメータ2>, …) As <データ型>
例：
Delegate Function SampleDelegate(ByVal value As Integer) As Integer
◇
デリゲートオブジェクトの生成 †
- デリゲートはクラスなので、利用する際にはNewキーワードでデリゲートオブジェクトを生成できる。
- デリゲートクラスのコンストラクタにはそのデリゲートと関連付けるメソッドをAddressOfキーワードを付けて指定する。
例：SampleDelegateのデリゲートオブジェクトMyDelegateにメソッドMethod1を関連付ける。
Dim MyDelegate As SampleDelegate = New SampleDelegate(AddressOf Method1)
◇
- ただし、関連付けることができるメソッドは、パラメータのデータ型の並びと戻り値のデータ型が一致する場合のみである。
例：これまでの例でいえば、メソッドMethod1は次のインタフェースである必要がある。
Function Method1(ByVal a As Integer) As Integer
◇
AddHandlerを使ったデリゲートとメソッドの関連付け †
AddHanderを使ってデリゲートとメソッドを関連付けることもできる。
例：サーバーベースタイマーであるSystem.Timers.TimerはElapseEventHandlerデリゲートを持つ。また、このタイマーを開始するときはEnabledプロパティをTrue、終了するときはEnabledプロパティをFalseに設定する。
0.1秒ごとに何らかの処理を行いたい場合は次のようにする。
1
2
3
4
5
6
7
8
9
10
11
12
| | Public Sub New()
…
Dim Timer1 As New System.Timers.Timer()
AddHandler Timer1.Elapsed, New ElapsedEventHandler(AddressOf Method1)
Timer1.Interval = 100
Timer1.Enabled = True
End Sub
Private Sub Method1(ByVal sender As Object, ByVal e As ElapsedEventArgs)
End Sub
|
これはツールボックスのコンポーネントからTimer（これはSystem.Windows.Forms.Timer）をフォームに貼り付けて、そのTimerのTickイベント時の処理として、0.1秒ごとに実行される処理を記述し、Intervalプロパティに100を設定しておけば、似たような動作は実現できる*1。
1
2
3
| | Private Sub Timer1_Tick(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Timer1.Tick
End Sub
|
なお、これを利用した例をVB.NET/テクニック/アイコンアニメーションで紹介している（System.Timers.Timerを利用）。 ◇
関連付けられたメソッドの呼び出し †
- メソッドをデリゲートに関連付けると、デリゲートを通じてメソッドを呼び出せる。
- 関連付けるメソッドにはインスタンスメソッド、共有メソッドのいずれも使用できる。
- インスタンスメソッドを関連付ける場合は、メソッドを呼び出すインスタンスを区別する。
例：
Method1(<パラメータ>)
を実行する代わりに、
MyDelegate(<パラメータ>)
で実行できる。
MyDelegateはオブジェクトだが、あたかもメソッドのように使える。 ◇
例：他クラスのインスタンスメソッドと共有メソッドをデリゲートに関連付ける。
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
| | Imports System
Class TestClass
Private text_ As String
Public Sub New(ByVal text As String)
text_ = text
End Sub
Public Sub Method1()
Console.writeLine(text_)
End Sub
Public Shared Sub Method2()
End Sub
End Class
Class Sample
Shared Sub Main()
Dim instance1 As New TestClass("test")
Dim action1 As New Action(AddressOf instance1.Method1)
action1()
Dim instance2 As New TestClass("test")
Dim action2 As New Action(AddressOf instance2.Method1)
action2()
Dim action3 As New Action(AddressOf TestClass.Method2)
action3()
End Sub
End Class
|
◇
ジェネリック・デリゲート †
Action<T>デリゲート †
.NET Framework 2.0のクラスライブラリ（System名前空間）には、次に示すジェネリック・デリゲートの宣言が含まれている。
デリゲートの活用 †
コールバック処理 †
メソッドのパラメータにデリゲートを渡して、そのメソッドの呼び出し先でデリゲートを実行することができる。
例：
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
| | Public Class Form1
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
Dim x As Integer = TripleData(Integer.Parse(TextBox1.Text))
Label1.Text = "計算結果： " & x
End Sub
Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
Dim x As Integer = HalfData(Integer.Parse(TextBox1.Text))
Label1.Text = "計算結果： " & x
End Sub
Private Function TripleData(ByVal n As Integer) As Integer
Return n * 3
End Function
Private Function HalfData(ByVal n As Integer) As Integer
Return n / 2
End Function
End Class
|
このプログラムではテキストボックスに入力した値を取り出して数字に変換する処理と、TripleData()やHalfData()で得た値をラベルに設定する箇所が重複している。また、テキストボックスから値を取り出す処理と、ラベルに計算結果を設定する処理は1処理のまとまりと考えることができる。
そこで、デリゲートを使うと次のように修正できる。
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
| | Public Class Form1
Delegate Function CalcDelegate(ByVal n As Integer) As Integer
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
Dim MyCalc As CalcDelegate = New CalcDelegate(AddressOf TripleData)
Process(MyCalc)
End Sub
Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
Dim MyCalc As CalcDelegate = New CalcDelegate(AddressOf HalfData)
Process(MyCalc)
End Sub
Private Sub Process(ByVal callBack As CalcDelegate)
Dim n As Integer = Integer.Parse(TextBox1.Text)
Dim x As Integer = callBack(n)
Label1.Text = "計算結果： " & x
End Sub
Private Function TripleData(ByVal n As Integer) As Integer
Return n * 3
End Function
Private Function HalfData(ByVal n As Integer) As Integer
Return n / 2
End Function
End Class
|
こうすることで、Process()の呼び出し元はテキストボックスからの値の取得やラベルに計算結果を設定するといった処理を意識することはない。Process()の呼び出し元であるボタンの押下イベントは、自身が何の目的のボタンであるかは把握しているため、計算に使用するメソッドだけを知るだけで十分である。
別スレッドからコントロールを操作する †
例：
1
2
3
4
5
6
7
8
9
10
11
| | #Region "テキストボックスに文字列入力制御"
Private Delegate Function InputDelegate(ByVal text As String) As Boolean
Private Function InputTextBox(ByVal text As String) As Boolean
TextBox1.Text = TextBox1.Text + text + vbCrLf
End Function
Private Sub invokeTextBox(ByVal dlg As InputDelegate, ByVal text As String)
TextBox1.Invoke(dlg, New Object() {text})
End Sub
#End Region
|
別スレッドから使用するときは次を実行する。
Dim dlg As New InputDelegate(AddressOf InputTextBox)
invokeTextBox(dlg, "文字列")
デリゲートとコーディング規約 †
- デリゲート名はPascal形式にする。
- イベント名はPascal形式にする。
- イベントで使用sるうためのデリゲートには"EventHandler"サフィクスを付ける。
- これによりイベントハンドラが登録されることが明確になり、可読性が向上sるう。
- 例：Public Delegate Sub MouseOverEventHandler(ByVal sender As Object, ByVal e As MouseEventArgs)
- イベントで使用するためのデリゲートはSubで宣言する。
- 戻り値があるデリゲートをイベントで使用することはできない。
参考文献 †
- 『Visual Basic 2008入門』
- 『VB.NETルールブック』
